게으른 엔지니어가 사는 법~~~

Modern UI 메뉴얼에 있는 예제 중에 하나인 WelcomeFinish.nsi를 한번 분석해 보자. 대부분의 내용은 앞에 basic.nsi에서 설명한 내용이라서 크게 설명할 내용이 없다. 단지 페이지중에 환영을 표시하는 윈도우와 마지막에 끝냄을 알리는 윈도우가 더 포함되어 있는게 다를 뿐이다. 똑같이 언인스톨시에도 환영 윈도우와 언인스톨을 끝냈다는 윈도우가 표시되는 것이다. 다른 부분은 특별히 설명할 내용이 없다.

[code];NSIS Modern User Interface
;Welcome/Finish Page Example Script
;Written by Joost Verburg

;--------------------------------
;Include Modern UI

  !include "MUI.nsh"

;--------------------------------
;General

  ;Name and file
  Name "Modern UI Test"
  OutFile "WelcomeFinish.exe"

  ;Default installation folder
  InstallDir "$PROGRAMFILES\Modern UI Test"

  ;Get installation folder from registry if available
  InstallDirRegKey HKCU "Software\Modern UI Test" ""

;--------------------------------
;Interface Settings

  !define MUI_ABORTWARNING

;--------------------------------
;Pages

  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_DIRECTORY
  !insertmacro MUI_PAGE_INSTFILES
  !insertmacro MUI_PAGE_FINISH

  !insertmacro MUI_UNPAGE_WELCOME
  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
  !insertmacro MUI_UNPAGE_FINISH

;--------------------------------
;Languages

  !insertmacro MUI_LANGUAGE "English"

;--------------------------------
;Installer Sections

Section "Dummy Section" SecDummy

  SetOutPath "$INSTDIR"

  ;ADD YOUR OWN FILES HERE...

  ;Store installation folder
  WriteRegStr HKCU "Software\Modern UI Test" "" $INSTDIR

  ;Create uninstaller
  WriteUninstaller "$INSTDIR\Uninstall.exe"

SectionEnd

;--------------------------------
;Descriptions

  ;Language strings
  LangString DESC_SecDummy ${LANG_ENGLISH} "A test section."

  ;Assign language strings to sections
  !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
    !insertmacro MUI_DESCRIPTION_TEXT ${SecDummy} $(DESC_SecDummy)
  !insertmacro MUI_FUNCTION_DESCRIPTION_END

;--------------------------------
;Uninstaller Section

Section "Uninstall"

  ;ADD YOUR OWN FILES HERE...

  Delete "$INSTDIR\Uninstall.exe"

  RMDir "$INSTDIR"

  DeleteRegKey /ifempty HKCU "Software\Modern UI Test"

SectionEnd
[/code]


31번째줄에 있는 환영 윈도우를 포함한 결과이다.


36번째 줄에 있는 완료 윈도우 화면이다.


38번째 줄에 있는 언인스톨시에 환영 윈도우이다.



41번째 줄에 있는 언인스톨시에 완료를 표시하는 윈도우 이다.


화면 캡쳐를 보면 한글로 나오는 것을 알 수 있다. 원래 예제 파일 자체를 컴파일해서 실행해 보면 영어로 되어 있다. 46번째줄을 보면 영어로 되어 있는 것을 확인할 수 있다. 그러면 한글로 보고 싶을 경우는 어떻게 하면 될까? 화면과 같이 한글로 나오게 할려면 46번째 줄만 수정하면 되지만, 69번째 줄을 보면 영어로 컴포넌트에 대한 설명을 적는 것을 볼 수 있다. 아래 화면을 보면 Dummy Section에 대한 상세 설명까지 한글로 되어 있다. 이렇게 한글을 보게 할려면 어떤 부분을 수정하면 될지 해보기 바란다.

크리에이티브 커먼즈 라이센스

이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.